Steps to Reproduce Behavior

1. Save the following code as File1.asp:

   <%
   '=============================================
   ' File1.asp - Run once to cache the template
   ' in an Application object.
   
   Dim oXSLDocument
   Set oXSLDocument = Server.CreateObject("MSXML2.FreeThreadedDOMDocument.3.0")
   oXSLDocument.async = False
   oXSLDocument.load(Server.MapPath("test.xsl"))
   
   Dim oXSLTemplate
   Set oXSLTemplate = Server.CreateObject("MSXML2.XSLTemplate.3.0")
   Set oXSLTemplate.stylesheet = oXSLDocument
   
   Set Application("CachedTemplate") = oXSLTemplate
   
   Set oXSLDocument = Nothing
   Set oXSLTemplate = Nothing
   %>
   					

2. Save the following code as File2.asp:

   <%
   '=============================================
   ' File2.asp - Each run consumes memory, without
   ' releasing it.
   
   Dim oInputDoc
   Dim oResourceDoc
   Dim oXSLProcessor
   
   Set oInputDoc = Server.CreateObject("MSXML2.DOMDocument.3.0")
   oInputDoc.loadXML "<Test>" & Now() & "</Test>"
   
   Set oResourceDoc = Server.CreateObject("MSXML2.DOMDocument.3.0")
   oResourceDoc.loadXML "<Resources/>"
   
   Set oXSLProcessor = Application("CachedTemplate").createProcessor()
   oXSLProcessor.input = oInputDoc
   oXSLProcessor.output = Response
   
   'Remove this line to stop the leak.
   oXSLProcessor.addParameter "resources", oResourceDoc.documentElement
   
   oXSLProcessor.transform()
   
   Set oResourceDoc = Nothing
   Set oInputDoc = Nothing
   Set oXSLProcessor = Nothing
   %>
   					

3. Save the following code as Test.xsl:

   <?xml version='1.0'?>
   <xsl:stylesheet xmlns:xsl="http://www.w3.org/TR/WD-xsl">
   	<xsl:template match="http://support.microsoft.com">
   	  XSL output: <xsl:value-of select="Test" />
   	</xsl:template>
   </xsl:stylesheet>
   					

4. Test the application under stress:
   1. Set up a new virtual folder and copy File1.asp, File2.asp, and Test.xsl to the virtual folder.
   2. Configure the new virtual folder to run in High Isolation - Out of Process, so that the ASP application runs under a separate copy of Dllhost.exe.
   3. From your browser, run File1.asp.
   4. From your browser, run File2.asp repeatedly.
   5. To view memory usage, start Windows Task Manager and click the Processes tab. One instance of Dllhost.exe shows linear growth in memory usage, corresponding to the memory leak.

Back to the top